這篇文章主要介紹ASP下通過Adodb.Stream實現多線程下載大文件的方法是什么，文中介紹的非常詳細，具有一定的參考價值，感興趣的小伙伴們一定要看完！
有個朋友 做 某種小眾音樂交換站的（他們那個行業的昵圖網），需要用到付費下載。嘗試過 防盜鏈，不太理想，最終使用了 Adodb.Stream 讀取，直接輸出。
解決了 盜版的問題，但是新的問題又來了。Adodb.Stream 這種方式 電腦還好說，大部分電腦瀏覽器都支持。移動端 很多 瀏覽器為了 加速讀取，會多線程下載導致 文件無法正常讀取。
抓包，發現增加了 HTTP頭 HTTP_RANGE。隱約記得 之前讀過 王大（王洪影）的 《深入解析 ASP核心技術》當中提到ASP多線程下載的問題，回家翻出來，最終還就真解決了。
為了 方便調用，直接寫成了 一個 函數。沒用王大的代碼，感覺我自己的更美（自戀中…）。如有有需要的朋友需要，直接拿走即可，代碼如下：
option explicit
'inputFile 需要下載的文件
'outputName 輸出文件名，可以為空，為空時自動根據 inputFile 生成
Sub CreateDownloader(byval inputFile, byval outputName)
Dim filePath
filePath = Server.Mappath(inputFile)
If outputName = "" Then outputName = Split(filePath, "\")(UBound(Split(filePath, "\")))
'下載開始
Dim AdoStream, bufferSize
Set AdoStream = Server.CreateObject("Adodb.Stream") 'Adodb.Stream，實例變量名為了方便區分用大寫
bufferSize = 2 * 1024 * 1024 '每次讀取大小(byte) 2M
AdoStream.Mode = 3 '1 讀，2 寫，3 讀寫
AdoStream.Type = 1 '1 二進制，2 文本
AdoStream.Open
AdoStream.LoadFromFile(filePath) '載入文件
Response.AddHeader "Content-Disposition", "attachment; filename=" & outputName '文件名
Response.ContentType = "application/octet-stream" '通知瀏覽器接受的文件類型(可自己定義,很多種,但一般都用這個
Dim httpRange,rangeStart,fileSize
'獲取 分段下載 請求
httpRange = Request.ServerVariables("HTTP_RANGE")
fileSize = AdoStream.size '文件總大小
If httpRange = "" Then
'不支持斷點續傳
rangeStart = 0
Else
'支持斷點續傳
httpRange = Mid(httpRange, 7)
rangeStart = CLng(Split(httpRange, "-")(0))
If rangeStart < 0 Or rangeStart >= fileSize Then
'已經下載完畢
Response.Status = "416 Requested range not satisfiable"
Else
Response.Status = "206 Partial Content"
Response.AddHeader "Content-Range", "bytes " & rangeStart & "-" & (fileSize - 1) & "/" & fileSize
AdoStream.Position = rangeStart
End If
End If
Dim binaryBlock
If Response.Status <> "416 Requested range not satisfiable" Then
Response.AddHeader "Content-Length", fileSize - rangeStart '通知瀏覽器接收的文件大小
binaryBlock = AdoStream.Read(bufferSize)
Do While Lenb(binaryBlock) > 0 '循環讀取直到讀完為止
Response.BinaryWrite binaryBlock '輸出二進制數據流
Response.Flush '立即發送(要求至少256字節)，不加的話可能提示超過緩存區。
binaryBlock = AdoStream.Read(bufferSize)
Loop
End If
AdoStream.Close '關閉文件對象
Set AdoStream = Nothing
Response.End
End Sub使用也非常簡單，假如上面的代碼保存到了 downloader.asp，直接引用即可：
<!--#include file="downloader.asp"-->
<%
'創建下載
call CreateDownloader("down/tools.rar", "")
'創建下載并自定義文件名
call CreateDownloader("down/tools.rar", "hello.rar")
%>有圖有真相：
以上是ASP下通過Adodb.Stream實現多線程下載大文件的方法是什么的所有內容，感謝各位的閱讀！希望分享的內容對大家有幫助，更多相關知識，歡迎關注億速云行業資訊頻道！
免責聲明：本站發布的內容（圖片、視頻和文字）以原創、轉載和分享為主，文章觀點不代表本網站立場，如果涉及侵權請聯系站長郵箱：is@yisu.com進行舉報，并提供相關證據，一經查實，將立刻刪除涉嫌侵權內容。
